Push-Nachrichten von MacTechNews.de
Würden Sie gerne aktuelle Nachrichten aus der Apple-Welt direkt über Push-Nachrichten erhalten?
Forum>Software>Überwachungssoftware

Überwachungssoftware

Stefan Lühr
Stefan Lühr09.06.0604:30
Moin,


folgendes Problem...

Ich will einen Raum mit einer Kamera überwachen. Bei einer festgestellten Bewegung soll ein Foto geschossen werden, das dann direkt per E-Mail versand wird.

Ich habe BTV Pro Carbon 4.1 und auch KeyCamX probiert. Beide bieten zwar die Möglichkeit die Bewegungserkennung durchzuführen, aber bisher bin ich daran gescheitert, die Bilder auch zu versenden. Beide speichern die Bilder (oder Videos - je nach Einstellung) in einem vorgegebenen Folder ab. KeyCamX kann per mitgeliefertem AppleScript eine Warnung per E-Mail versenden, allerdings fehlt das Bild. Das wird nur lokal abgespeichert. Man kann es zwar auch per FTP automatisch hochladen lassen, allerdings hätte ich doch lieber das Bild per E-Mail.

Ich habe auch etwas mit Automator herumgespielt, konnte aber nix zusammenklicken was das folgende macht:
Nimm zuletzt zu einem Verzeichnis hinzugefügte Datei, versende sie per E-Mail und lösche sie dann (oder benenne sie um mit einem Namen, der Datum und Zeit enthält, und verschiebe sie dann in ein anderes Verzeichnis).

Ideen?

mfg

Stefan
0

Kommentare

Apfelholgi
Apfelholgi09.06.0609:49
hm, ich hätte jetzt zu Automator geraten, aber das probierst du ja bereits. Ich würde mal sagen: dranbleiben.

Das wird schon, wie bei allen Skripting-Sachen erfordert es halt etwas Geduld.

Aber ich hab davon auch wenig Ahnung, ich muss mir meine Geduld für FileMaker-Skripts aufheben...:-P
„if it looks like it works and it feels like it works than it works!“
0
macalex09.06.0611:14
Hallo Stefan, also das funktioniert bei mir mit SecuritySpy.
Habe es gerade ausprobiert (brauche diese Funktion eigentlich nicht).
Beim jeweiligen Camera-Setup unter Actions "Send email to".
Einstellen wieviele Bilder gesendet werden sollen bei einer Bewegung, etc.
Wichtig bei Compression Settings die Qualität einstellen für email.
Vielleicht einfach mal das ausprobieren: "www.securityspy.com" Demo
0
_mäuschen
_mäuschen09.06.0614:21
Als Plug-in sichern
Plug-in für: Ordneraktionen
Angehängt an Ordner: "_ * Ordner NEU"

Schritt 1-3 die e-mail
Schritt 4 beinhaltet den Pfad zu dem Ordner an den diese FA angehängt ist
Schritt 5-6 selektiert das Bild
Schritt 7 verschiebt das Bild
Schritt 8 beinhaltet den Pfad zu "_ * Ordner ALT"
Schritt 9&10 das Bild selektieren
Schritt 11 umbenennen.
0
_mäuschen
_mäuschen09.06.0618:05
sorry, falsches Bild hochgeladen
dieses passt nun besser zum Text
0
tk69
tk6909.06.0618:28
macalex
Hallo Stefan, also das funktioniert bei mir mit SecuritySpy.
Habe es gerade ausprobiert (brauche diese Funktion eigentlich nicht).
Beim jeweiligen Camera-Setup unter Actions "Send email to".
Einstellen wieviele Bilder gesendet werden sollen bei einer Bewegung, etc.
Wichtig bei Compression Settings die Qualität einstellen für email.
Vielleicht einfach mal das ausprobieren: "www.securityspy.com" Demo

Hi,

wo speichert er die aufgenommenen Daten ab?

Und wo kann man den Speicherort einstellen?

Danke, cu und Gruß
tk

0
_mäuschen
_mäuschen10.06.0620:09
Stefan Lühr, hier ein AppleScript den man als OrdnerAktion anhängt.


Die addrVar anpassen.

Zum Austesten displayForManualSend auf true setzen
Zum wirklich die e-mail senden auf false


=========== code ===========

property addrVar : "a@b.c" -- Hier die Empfänger Adresse anpassen

property subjectvar : "new photo Attachment! " & (current date)
property bodyvar : return & return & "New photo" & ¬
return & (current date) & return

property displayForManualSend : false

on adding folder items to this_folder after receiving added_items --
set this_item to item 1 of added_items
tell application "Mail"
set composeMessage to ¬
(make new outgoing message with properties ¬
{visible:true, content:" "})
tell composeMessage
make new to recipient at beginning of to recipients ¬
with properties {address:addrVar}
set the subject to subjectvar
set the content to bodyvar
tell content
make new attachment ¬
with properties {file name:this_item} at ¬
after the last character
end tell
end tell
if displayForManualSend then
display dialog "Ja wir sind zum Testen da." & return & "Falleri, fallera"
else
send composeMessage
end if
end tell
end adding folder items to

0
Thomas Schulz
Thomas Schulz10.06.0622:05
SecuritySpy ist hochgeil!

Habs mir sofort gekauft. Es lädt Dir Dir Bilder auf einen Server Deiner Wahl oder schickt Dir ein Mail mit einem Film und Bildern. Du kannst alles einstellen.

Geht auch mit der iSight.

Perfekt. Genau so etwas habe ich auch gesucht. Kosten ca 440 € - also verkraftbar.
„Keep it quick and simpel
0
Stefan Lühr
Stefan Lühr10.06.0622:36
Thomas Schulz
SecuritySpy ist hochgeil!

Perfekt. Genau so etwas habe ich auch gesucht. Kosten ca 440 € - also verkraftbar.

Nun.. 440 EUR ist etwas über meinem Limit
Dafür lerne ich lieber Automator und Apple Script dann kann man das mit einem preiswerteren Programm auch hinbekommen. Mäuschen ist ja hier offenbar der (die) absolute Experte(in)

mfg

Stefan
0
Max_volume
Max_volume11.06.0613:44
Kurze Frage zu SecuritySpy.
Wenn man da die Demo runterläd. Oder eben das Programm und es nicht erwirbt. Funktioniert es dann auch oder tut es nur, wenn man es kauft?
0
macalex12.06.0617:18
Max_volume

Demo funktioniert ganz normal bis auf einen Hinweis (Rechteck) in der Mitte des Bildes oder Filmes das aufgenommen wird. Zum testen und ausprobieren eine gute Lösung wie ich finde.


tk69
Einstellung im jeweiligen Kamera Setup


Es handelt sich auch um andere Preise bei SecuritySpy:
Tippfehler 440 ?
Die Preise sind gestaffelt, je nach dem wieviele Kameras man verwendet.
0
_mäuschen
_mäuschen12.06.0623:44
Hier die Variante welche die Datei als mail sendet,
verschiebt und den Dateinamen um das aktuelle Datum erweitert.

=====================================================
(* *)
property addrVar : "tempo23@bluemail.ch"
(* *)
property namVar : "abc"
(* *)
property subjectvar : "new photo Attachment! " & (current date)
(* *)
property bodyvar : return & return & "New photo" & ¬
return & (current date) & return

(* if set to false the mail will be sent immediately *)
property displayForManualSend : true
property destination_folder : "doneFolder" -- inside this_folder

on adding folder items to this_folder after receiving added_items

(* Don't send the destination_folder at it's creation time *)
if destination_folder is not in (added_items as string) then

(*do the job *)
tell application "Mail"
launch
set composeMessage to ¬
(make new outgoing message with properties ¬
{visible:true, content:" "})
tell composeMessage
make new to recipient at beginning of to recipients ¬
with properties {name:namVar, address:addrVar}
set the subject to subjectvar
set the content to bodyvar
tell content
repeat with this_item in added_items
make new attachment ¬
with properties {file name:this_item} ¬
at after the last character
end repeat
end tell
end tell
if displayForManualSend then
display dialog "Ja wir sind zum Testen da." & ¬
return & "Falleri und fallera" giving up after 1
else
send composeMessage
end if
end tell
end if

(* do the rest *)
tell application "Finder"
activate
(* destination_folder will be created
at very first run of this folder action. So it's creation time *)

if not (exists folder destination_folder of this_folder) then
make new folder at this_folder ¬
with properties {name:destination_folder}
end if

set source_folder to this_folder
set dest_folder to folder destination_folder of this_folder

repeat with this_item in added_items

(* copy the file *)
duplicate (this_item as alias) to ¬
(dest_folder as alias) with replacing

(* prepare for new name for the copied file *)
set new_item to (dest_folder as string) & ¬
(name of (info for this_item as alias)) as string

(* get new file name *)
set new_name to name of (info for new_item as alias)

(* get file extension *)
set ext to name extension of (info for new_item as alias)

set has_ext to false
(* do we have an extension? *)
if ext is not missing value then
(* Yes, we have an extension!

get the name only *)

set new_name to (characters 1 thru ¬
((offset of ext in new_name) - 2) ¬
of new_name as string)

(* and re-dot the extension*)
set ext to "." & ext
set has_ext to true
end if

(* add a time stamp to the name *)
set new_name to new_name & ¬
my dateFormat(current date)

(* and complete with the extension (if any) *)
if has_ext then set new_name to new_name & ext

(* rename the copied file *)
set name of (new_item as alias) to new_name

(* delete recently added file > move to thrash*)
delete (this_item as alias)
end repeat

(* give me five *)
end tell
end adding folder items to

on dateFormat(theDate)
set {year:y, day:d, time:t} to theDate
copy theDate to b
set b's month to January
set totalSeconds to t
set theHour to totalSeconds div hours
set theMinutes to (totalSeconds mod hours) div minutes
set theSeconds to totalSeconds mod minutes
if theHour < 10 then set theHour to "0" & theHour
if theMinutes < 10 then set theMinutes to "0" & theMinutes
if theSeconds < 10 then set theSeconds to "0" & theSeconds

(* nicely formated time stamp *)
set the_time to ¬
theHour & "´" & ¬
theMinutes & "´" & ¬
theSeconds
tell (y * 10000 + (b - 2500000 - theDate) ¬
div -2500000 * 100 + d) as string
set dateString to " ~" & text 1 thru 4 & "/" & ¬
text 5 thru 6 & "/" & text 7 thru 8 & "_" & the_time
end tell
return dateString
end dateFormat
=====================================================
0
_mäuschen
_mäuschen12.06.0623:52
Wer findet die editierfreudigen Wörter im obigen Text?
0

Kommentieren

Diese Diskussion ist bereits mehr als 3 Monate alt und kann daher nicht mehr kommentiert werden.