Moin,

wer kann mir einen Ratschlag geben, wie ich am einfachsten
und schnellsten einen Dateifolder in eine .iso-Datei konvertiere??

Danke!

Erstelle mit dem Festplattendienstprogramm ein Image in der erforderlichen Grösse.

Kopiere die Daten oder den Ordner nach dem .dmg
und konvertiere es mit diesem Terminal Befehl nach .iso

hdiutil convert /path/to/filename.dmg -format UDTO -o /path/to/savefile.iso

Moin.

Hab das noch nie gemacht, aber kann Toast das nicht auch??
Da steht immer was von ISO 9660 ....

_mäuschen

mmh, hört sich (zumindest für mich) relativ kompliziert an..., gibts da
vielleicht ein Automatormakro oder Tool welches dir bekannt ist??

FALLS du Toast hast. "Save as disk image..", Datei von .toast nach .iso umbennen.

Falls nicht, so ist _mäuschens Tip sicher gratis, und gar nicht so kompliziert.

Diesen Automator Workflow als Finder Plugin mit Namen 'Create ISO' speichern

Datei(en) oder Ordner selektieren, RechtsKlick, 'Automator » Create ISO' auswählen

und Du erhälst ein .ISO.cdr


-- Create image and convert to ISO

on run {input, parameters}
-- Set some basic details about the file
tell application "Finder"
set noFiles to count input
set fileKind to kind of item 1 of input
end tell

-- If there is nothing selcted, cancel action
if noFiles = 0 then
display dialog "There are no files or folders selected. Please select some and try again" buttons {"OK"} default button 1

-- Is it a folder, or a group of files?
else if noFiles = 1 and fileKind is "Folder" then
tell application "Finder"
-- Get the folder
set theFile to item 1 of input

-- Pick a name for the image
set imageName to name of theFile
set imageName to text returned of (display dialog "Please choose a name for the Disk Image" default answer imageName)

-- Pick location for image
set imageLocation to container of theFile as string
set imageLocation to POSIX path of imageLocation
set imageLocation to quoted form of (imageLocation & imageName & ".dmg")

-- Original Location
set originalFile to theFile as string
set originalFile to quoted form of POSIX path of originalFile
end tell

-- Now make it!
do shell script "hdiutil create -srcfolder " & originalFile & " -volname " & quoted form of imageName & " " & imageLocation

-- Convert to ISO
do shell script "hdiutil convert" & " " & quoted form of (imageLocation & imageName & ".dmg") & " " & "-format UDTO -o" & " " & quoted form of (imageLocation & imageName & ".ISO")
do shell script "rm" & " " & quoted form of (imageLocation & imageName & ".dmg")

-- Ask if I want the folder deleted
tell application "Finder"
set deleteOriginal to display dialog "The Disk Image was successfully created. Do you wish to delete the original folder?" buttons {"Keep", "Delete"} default button "Delete"
if button returned of deleteOriginal is "Delete" then delete theFile
end tell

else
tell application "Finder"

-- Pick a default name for the image
if noFiles = 1 then
-- If there is only one item set default to its name
set imageName to name of item 1 of input
else
-- Otherwise use "My Disk Image"
set imageName to "My Disk Image"
end if
-- Ask the user for the disk's name
set imageName to text returned of (display dialog "Please choose a name for the Disk Image" default answer imageName)

-- Where the Image will end up
set imageLocation to container of (item 1 of input) as string
set imageLocation to POSIX path of imageLocation

-- Set up the temp folder
set tempFolder to imageLocation & ".DiskImageTemp/"
end tell

-- Attempt to remove any previous temp folders
try
do shell script "rm -r " & quoted form of tempFolder
end try

-- Copy the files for the disk image to the tmp folder
do shell script "mkdir " & quoted form of tempFolder
repeat with i from 1 to noFiles
tell application "Finder"
set originalFile to quoted form of POSIX path of (item i of input as string)
set newfile to quoted form of (tempFolder & name of item i of input)
end tell

-- Copy the files
try
do shell script "cp " & originalFile & " " & newfile
on error
do shell script "cp -R " & originalFile & " " & newfile
end try
end repeat

-- Create the disk image
do shell script "hdiutil create -srcfolder " & quoted form of tempFolder & " -volname " & quoted form of imageName & " " & quoted form of (imageLocation & imageName & ".dmg")

-- Delete the temporary files
do shell script "rm -r " & quoted form of tempFolder

tell application "Finder"
-- Convert to ISO
do shell script "hdiutil convert" & " " & quoted form of (imageLocation & imageName & ".dmg") & " " & "-format UDTO -o" & " " & quoted form of (imageLocation & imageName & ".ISO")
do shell script "rm" & " " & quoted form of (imageLocation & imageName & ".dmg")

-- Delete the original?
set deleteOriginal to display dialog "The Disk Image was successfully created.

Do you wish to delete the original file(s)?" buttons {"Keep", "Delete"} default button "Delete"

if button returned of deleteOriginal is "Delete" then
repeat with i from 1 to (count (input))
delete item i of input
end repeat
end if
end tell

end if
end run

Schau dir mal Firestarter FX an:

Das ist ein kostenloses Brennprogramm, dass sich diverser Tools aus dem Linuxbereich bedient, wie z.B. mkisofs.

FireStarter FX is now donation-ware:

If you like FireStarter FX and use it,
please support it by making donations.

_mäuschen

cool, danke für den workflow! it works