tell application "Finder" to shut down

on theCommands(thePassword)
    --do shell script "say \"Hello\""
    
    do shell script "pmset  -a slower 0 spindown 5 dim 5 sleep 5" password thePassword with administrator privileges
    
    do shell script "sudo -k" --Zeitfenster von sudo schließen
end theCommands


property myKeyName : "adminpwd"
property keyDescription : "Administrator-Kennwort"
property theAppName : "Startobjekteskript"
property theAppVersion : "Rev. 2"


on run
    set theKey to getKey()
    tell application "Keychain Scripting" to set thePassword to password of theKey
    theCommands(thePassword)
end run


on getKey()
    set validKey to false
    set changedPassword to false
    tell application "Keychain Scripting"
        set theKeychain to current keychain
        tell theKeychain
            if locked then
                tell me to display dialog "'Keychain Scripting' bittet gleich um das Passwort für den Schlüsselbund  '" & name of theKeychain & ¬
                    "' einzugeben. Das ist in Ordnung." buttons {"OK"} default button 1
                unlock --provoziert Passworteingabeaufforderung vom Schlüsselbund
            end if
            set theKey to every generic key of theKeychain whose name is myKeyName
            if theKey = {} then
                set theKey to my makeKey()
                set firstTime to true
                set validKey to true
            else
                set theKey to item 1 of theKey
                set firstTime to false
            end if
        end tell --end tell theKeychain    
    end tell --end tell application "Keychain Scripting"
    repeat while not validKey
        tell application "Keychain Scripting" to set thePassword to the password of theKey
        try
            do shell script "sudo -k" --timeout our sudo ability so the following test is valid            
            do shell script "ls /private/var/root/" password thePassword with administrator privileges
            do shell script "sudo -k" --Zeitfenster von sudo schließen
            set validKey to true
        on error
            set thePassword to text returned of ¬
                (display dialog "Das Administrator-Passwort für " & theAppName & " ist ungültig. Bitte korrigieren. Das Passwort wird bei der Eingabe zwar im Klartext angezeigt, gespeichert wird es im Schlüsselbund jedoch verschlüsselt." default answer "" with icon caution)
            set changedPassword to true
            set validKey to false
        end try
    end repeat
    if changedPassword then tell application "Keychain Scripting" to set the password of theKey to thePassword
    if firstTime then
        display dialog "Damit '" & theAppName & "' zukünftig ohne Ihr Zutun laufen kann, müssen Sie ihm Zugriffe auf den Schlüsselbund erlauben. Klicken Sie im ersten Dialog 'Immer erlauben' an, im zweiten 'Einmal erlauben'." buttons {"OK"} default button 1
    end if
    return theKey
end getKey


on makeKey()
    set validKey to false
    display dialog "'" & theAppName & "' fragt Sie jetzt nach Ihrem Administrator-Passwort, um es für zukünftige Nutzung sicher im Schlüsselbund abzulegen. Diese Abfrage erscheint dann nicht mehr."
    repeat while not validKey
        set thePassword to text returned of (display dialog "Das Passwort wird bei der Eingabe zwar im Klartext angezeigt, gespeichert wird es im Schlüsselbund jedoch verschlüsselt. Geben Sie Ihr Administrator-Passwort ein:" default answer "" with icon caution)
        try
            do shell script "sudo -k" --Zeitfenster von sudo schließen
            do shell script "ipfw list" password thePassword with administrator privileges
            do shell script "sudo -k" --Zeitfenster von sudo schließen            
            set validKey to true
        on error
            display dialog "Das Passwort ist ungültig. Bitte geben Sie ein anderes ein." buttons {"OK"} default button 1 with icon caution
            set validKey to false
        end try
    end repeat
    tell application "Keychain Scripting"
        set theKeychain to current keychain
        set username to system attribute "USER"
        set theComment to "angelegt von '" & theAppName & " " & (theAppVersion as text) & "'"
        set myKey to (make new generic key at theKeychain with properties ¬
            {name:myKeyName, description:keyDescription, account:username, comment:theComment, password:thePassword})
    end tell --end tell application Keychain Scripting
    return myKey
end makeKey

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
    <key>TALAppsToRelaunchAtLogin</key>
    <array>
        <dict>
            <key>Background</key>
            <false/>
            <key>BundleID</key>
            <string>com.apple.finder</string>
            <key>Hide</key>
            <false/>
            <key>Path</key>
            <string>/System/Library/CoreServices/Finder.app</string>
        </dict>
    </array>
</dict>
</plist>