property printWindow : "Drucken"
property safePDF : "Als PDF sichern …"
property mySafeWindow : "Sichern"
property doNewPath : "Start"
property doSaveButton : "Sichern"
property myReplace : "Ersetzen"

property out_folder : "PDFs"

on adding folder items to theFolder after receiving theFiles
    main_action(theFolder, theFiles)
end adding folder items to

on run
    -- mainly for debugging
    set f to choose file
    tell application "System Events"
        set theFolder to (path of (container of f))
    end tell
    set theFolder to alias theFolder
    main_action(theFolder, {f})
end run

on main_action(theFolder, theFiles)
    
    tell application "System Events"
        if not (exists folder out_folder of theFolder) then
            make new folder at end of theFolder with properties {name:out_folder}
        end if
        set f_name to name of theFolder
    end tell
    
    set out_path to (POSIX path of theFolder) & out_folder & "/"
    
    repeat with X from 1 to count theFiles
        set curr to item X of theFiles
        tell application "RagTime 6.5"
            activate
            open curr
        end tell
        set pdfName to name of (info for (curr))
        set pdfName to (characters 1 thru -5 of pdfName) as string
        tell application "System Events"
            tell process "RagTime"
                -- Press command+p to open our print dialog
                keystroke "p" using command down
                
                -- Let's make sure our print dialog is up
                repeat until exists window printWindow
                end repeat
                
                -- Click the PDF menu button
                click menu button "PDF" of window printWindow
                
                -- Make sure the menu is up
                repeat until exists menu item safePDF of menu 1 of menu button "PDF" of window printWindow
                end repeat
                
                -- Select the "Save as PDF" menu item
                click menu item safePDF of menu 1 of menu button "PDF" of window printWindow
                
                -- Make sure the save dialog is visible
                repeat until exists window mySafeWindow
                end repeat
                
                -- Press command+shift+g to show the "Go" drop down sheet
                keystroke "g" using {command down, shift down}
                
                --Set our location field to our pdfSavePath            
                set value of text field 1 of sheet of window mySafeWindow to out_path
                
                -- Now click the Go button
                click button doNewPath of sheet of window mySafeWindow
                
                -- Now that we are in our desired folder, set the file name and save
                set value of text field 1 of window mySafeWindow to pdfName & ".pdf"
                click button doSaveButton of window mySafeWindow
                
                if exists sheet 1 of window mySafeWindow then
                    click button myReplace of sheet 1 of window mySafeWindow
                end if
                
                delay 1
                keystroke "w" using {command down}
            end tell
        end tell
    end repeat
end main_action