Gibt es eine Möglichkeit zu überprüfen, ob es sich bei einer Variablem um eine Zahl handelt?
Hatte es mit if variable is not real then … probiert. Das funktioniert leider nicht.
Danke im Voraus.

if (class of foo is integer) or (class of foo is real) then

Funktioniert nicht.
Habe:
set Feld to Feld as real
if (class of Feld is not integer) or (class of Feld is not real) then set Feld to 0

Egal was ich in Feld dann eingebe, es wird immer auf 0 gesetzt.

Und, wie erstelle ich ein else?
Habe:
if (class of Feld1 is integer) or (class of Feld1 is real) then set Feld1 to Feld1

Wenn ich nun dahinter ein else schreibe kommt eine Fehlermeldung, von wegen Zeilenende, etc erwartet.

Da Du ja den möglichen Integer mit set Feld to Feld as real nach Real wandelst

genügt

if not class of Feld is real then set Feld to 0

Ja, das ist es! Vielen Dank!!!

Oder auch nicht.
Es wird nun nicht mehr zur 0 verwandelt, aber wenn es kein real ist bekomme ich den display alert, also es wird nicht zur 0 gewandelt.

Könnte es daran liegen, dass egal was ich ins Textfeld eingebe es in real gewandelt wird, daher wirds nicht zur 0 gewandelt. Und die Fehlermeldung bekomme ich weil es ja dann keine real zahl ist, obwohl sie als solche deklariert ist?!?
Wie kann ich das Problem lösen?

Wenn Du Text eingibst:-/ und nach Real wandelst?

Ja. Ich will es Idiotensicher machen.

Im Grunde muss ich ja die Überprüfung vor dem ins Real wandeln machen. Nur dort ist es ja noch ein String, also wird nicht als Real oder Integer erkannt.

try
set foo to foo as real
on error
display dialog "You did not enter a (valid) number."
end try

Vielleicht gibt es ja auch eine Möglichkeit, dass man von vornherein nur Zahlen in das Textfeld eingeben kann…

Im Grunde habe ich es so. Nur missfällt mir daran, dass sich das Programm dann beendet. Außerdem habe ich 3 Felder, sodass selbst wenn beim ersten keine Zahl eingegeben wurde noch die nächsten beiden erscheinen.

Dass sich das Programm, dann nicht beendet, sondern neustartet, bekomme ich noch hin.
Bleibt das Problem, das die weiteren Fenster trotzdem noch angezeigt werden.

Ah, hab gerade eine Idee…

Habs. Danke für deine Anregungen.

Zeig mal das Ganze im Kontext

on run
set Feld1 to text returned of (display dialog "Energie (kcal) pro 100g:" default answer "" buttons {"Weiter"} default button 1)
try
set Feld1 to Feld1 as real
set Feld2 to text returned of (display dialog "Fett (g) pro 100g:" default answer "" buttons {"Weiter"} default button 1)
set Feld2 to Feld2 as real
set Feld3 to text returned of (display dialog "Portionsgröße (g):" default answer 100 buttons {"Berechne"} default button 1)
set Feld3 to Feld3 as real
set ergebnis to ((Feld1 / 60) + (Feld2 / 9)) * (Feld3 / 100)
set ergebnis to (round (ergebnis * 10) rounding as taught in school) / 10
set ergebnis to ergebnis as string
set Feld1 to (round (Feld1))
set Feld3 to (round (Feld3))
display dialog ergebnis & " Points" & return & return & "Energie: " & tab & tab & tab & Feld1 & " kcal" & return & "Fett : " & tab & tab & tab & Feld2 & " g" & return & "Portionsgröße: " & tab & Feld3 & " g" buttons {"Fertig"} & {"Erneut berechen"} default button 2
if button returned of result = "Erneut berechen" then run
on error
display dialog "Fehler!!!" buttons {"Abbrechen"} & {"Erneut berechen"} default button 2
if button returned of result = "Erneut berechen" then run
end try
end run

Ein Fehler ist noch drin.
Wenn man ein paar mal die Rechnung durchgeführt hat und danach ein Fehler kommt, muss man genauso oft auf Abbrechen drücken, wie man vorher die Rechnung wiederholt hat. Mir ist auch klar warum aber mir fällt nicht ein wie ich es lösen könnte. Hast du vielleicht eine Idee?

Etwa in so


repeat
repeat
set theResult to display dialog ¬
"Energie (kcal) pro 100g:" default answer "Integer oder Real"
set foo to text returned of theResult
try
set foo to foo as real
end try
if class of foo is real then
set Feld1 to foo
exit repeat
end if
end repeat
repeat
set theResult to display dialog ¬
"Fett (g) pro 100g:" default answer "Integer oder Real"
set foo to text returned of theResult
try
set foo to foo as real
end try
if class of foo is real then
set Feld2 to foo
exit repeat
end if
end repeat
repeat
set theResult to display dialog ¬
"Portionsgröße (g):" default answer "Integer oder Real"
set foo to text returned of theResult
try
set foo to foo as real
end try
if class of foo is real then
set Feld3 to foo
exit repeat
end if

end repeat
set ergebnis to ((Feld1 / 60) + (Feld2 / 9)) * (Feld3 / 100)
set ergebnis to (round (ergebnis * 10) rounding as taught in school) / 10
set ergebnis to ergebnis as string
set Feld1 to (round (Feld1))
set Feld3 to (round (Feld3))
display dialog ergebnis & " Points" & return & return & "Energie: " & tab & tab & tab & Feld1 & " kcal" & return & "Fett : " & tab & tab & tab & Feld2 & " g" & return & "Portionsgröße: " & tab & Feld3 & " g" buttons {"Fertig"} & {"Erneut berechen"} default button 2
if button returned of result = "Fertig" then exit repeat
end repeat

Genial!
Eine Sache ist noch. Wenn man überhaupt nichts eingibt bekommt man eine Fehlermeldung aber das schaff ich schnell auszumurksen.
Vielen vielen Dank!!!

So ist perfekt

repeat
repeat
set theResult to display dialog ¬
"Energie (kcal) pro 100g:" default answer ""
set foo to text returned of theResult
try
if foo is "" then set foo to "0"
set foo to foo as real
end try
if class of foo is real then
set Feld1 to foo
exit repeat
end if
end repeat
repeat
set theResult to display dialog ¬
"Fett (g) pro 100g:" default answer ""
set foo to text returned of theResult
try
if foo is "" then set foo to "0"
set foo to foo as real
end try
if class of foo is real then
set Feld2 to foo
exit repeat
end if
end repeat
repeat
set theResult to display dialog ¬
"Portionsgröße (g):" default answer "100"
set foo to text returned of theResult
try
if foo is "" then set foo to "0"
set foo to foo as real
end try
if class of foo is real then
set Feld3 to foo
exit repeat
end if

end repeat
set ergebnis to ((Feld1 / 60) + (Feld2 / 9)) * (Feld3 / 100)
set ergebnis to (round (ergebnis * 10) rounding as taught in school) / 10
set ergebnis to ergebnis as string
set Feld1 to (round (Feld1))
set Feld3 to (round (Feld3))
display dialog ergebnis & " Points" & return & return & "Energie: " & tab & tab & tab & Feld1 & " kcal" & return & "Fett : " & tab & tab & tab & Feld2 & " g" & return & "Portionsgröße: " & tab & Feld3 & " g" buttons {"Fertig"} & {"Erneut berechen"} default button 2
if button returned of result = "Fertig" then exit repeat
end repeat


*freu*

oder so ? 

Danke mäuschen!!!
Durch dich lerne ich echt viel Applescript.
Habe erst am Donnerstag angefangen…