Hi,
gibt es irgendwo ein Script, welches nach und nach alle Videodateien in einen Ordner, bzw. alle ausgewählten Dateien von dem Ursprungsformat in ein anderes wie z.B. das für iPod.
Es ist nämlich lästig immer 30-40 Min zu warten bis ein Film fertig ist um dann den einen neuen auszuwählen und zu konvertieren.
Dann könnte ich meinen Rechner endlich Tags einfach laufen lassen und er tut was dabei und ist nicht nach ein paar Minuten wieder arbeitslos bis ich wieder zuhause bin.

QT kann mehrere Dateien gleichzeitig exportieren.
Die Original movie-Fenster kann man schliessen

gleichzeitig ist aber viel langsamer.
Wenn ich 2 gleichzeitig exportiere dauert das länger als wenn ich 2 nacheinander exportiere. Daher würde ich gerne nach und nach machen da es schneller geht.
Hab schon Automator angeguckt, ist aber nichts brauchbares zu finden.

Wenn du sowieso nicht zu Hause bist, ist es doch nicht schlimm wenn es länger dauert.

naja, es aber wenn ich wenn ich x Vids mehr in der gleichen Zeit umcodiert haben kann, dann geb ich mich doch nicht weniger zufrieden.
Zudem denke ich das QT es nicht gerne hätte (und meine Rechner sicher auch nicht) wenn ich ihn 20 oder 30 Vids aufeinmal umcodieren lasse.

Vergewissere Dich dass in QT 7 Pro das erwünschte Export Format eingestellt
z.Bsp.: Film iPod (320x 240)


Speichere nachstehenden Ordner Aktionen - AppleScript

in @@ ~/Library/Scripts/Folder Action Scripts
(wenn er noch nicht existiert > erstellen. Leerschläge beachten)

als mov2mov.scpt


Erstelle einen neuen Ordner z.Bsp.: _to_do
ausser- oder innerhalb des Ordners der zu konvertierenden Filme

Rechts-click auf diesen neuen Ordner _to_do
Ordneraktion anhängen >> mov2mov.scpt


Verschiebe nun Deine gewünschten Videodateien in _to_do und ....


..... geh schlafen

-- Dieser FolderAction script konvertiert Movies
-- mit dem in QT 7 Pro eingestellten MPEG4 Exportformat
-- eg Film iPod (320x 240)
-- nochbereinigungsbedürftigdaaufdieschnellezwischenabendbrotundscifimovieetc:-[
-- _mäuschen
-- AS templates by&@ Apple
property done_foldername : "_iPodMovies"
property originals_foldername : "_Originals"
property newmovie_extension : "m4v" -- von Hand zu setzen
-- the list of file types which will be processed
property type_list : {"AVI", "MooV", "QuickTime movie", "MPEG4"}
-- since file types are optional in Mac OS X,
-- check the name extension if there is no file type
-- NOTE: do not use periods (.) with the items in the name extensions list
property extension_list : {"avi", "mov", "moov", "movie", "mpg", "mp4", "mpeg", "m4v"}

on adding folder items to this_folder after receiving these_items
-- this routine uses the gestaltVersion_info() sub-routine
copy my gestaltVersion_info("qtim", to {QT_version, QT_string}
if the QT_version is less than "0700" then
display dialog "This script requires QuickTime 7.0.0 Pro or higher." & ¬
return & return & "The currently installed version is: " & ¬
QT_string buttons {"Cancel"} default button 1
end if
tell application "Finder"
if not (exists folder done_foldername of this_folder) then
make new folder at this_folder with properties {name:done_foldername}
end if
set the results_folder to (folder done_foldername of this_folder) as alias
if not (exists folder originals_foldername of this_folder) then
make new folder at this_folder with properties {name:originals_foldername}
set current view of container window of this_folder to list view
end if
set the originals_folder to folder originals_foldername of this_folder
end tell
try
repeat with i from 1 to number of items in these_items
set this_item to item i of these_items
set the item_info to the info for this_item
if (alias of the item_info is false and the file type of the item_info is in the type_list) or (the name extension of the item_info is in the extension_list) then
tell application "Finder"
my resolve_conflicts(this_item, originals_folder, "")
set the new_name to my resolve_conflicts(this_item, results_folder, newmovie_extension)
set the source_file to (move this_item to the originals_folder with replacing) as alias
end tell
process_item(source_file, new_name, results_folder)
end if
end repeat
on error error_message number error_number
if the error_number is not -128 then
tell application "Finder"
activate
display dialog error_message buttons {"Cancel"} default button 1 giving up after 120
end tell
end if
end try
end adding folder items to

on resolve_conflicts(this_item, target_folder, new_extension)
tell application "Finder"
set the file_name to the name of this_item
set file_extension to the name extension of this_item
if the file_extension is "" then
set the trimmed_name to the file_name
else
set the trimmed_name to text 1 thru -((length of file_extension) + 2) of the file_name
end if
if the new_extension is "" then
set target_name to file_name
set target_extension to file_extension
else
set target_extension to new_extension
set target_name to (the trimmed_name & "." & target_extension) as string
end if
if (exists document file target_name of target_folder) then
set the name_increment to 1
repeat
set the new_name to (the trimmed_name & "." & (name_increment as string) & "." & target_extension) as string
if not (exists document file new_name of the target_folder) then
-- rename to conflicting file
set the name of document file target_name of the target_folder to the new_name
exit repeat
else
set the name_increment to the name_increment + 1
end if
end repeat
end if
end tell
return the target_name
end resolve_conflicts

-- this sub-routine processes files
on process_item(source_file, new_name, results_folder)
-- NOTE that the variable source_file is a file reference in alias format
-- FILE PROCESSING STATEMENTS GOES HERE
try
-- the target path is the destination folder and the new file name
set the target_path to ((results_folder as string) & new_name) as string
with timeout of 3600 seconds -- one hour per movie time limit
tell application "QuickTime Player"
activate
-- SUPPRESS AUTOPLAY AND AUTOPRESENT PROPERTIES IN ORDER TO WORK WITH THE MOVIE
my toggle_suppress(true)
-- STOP AND CLOSE ANY EXISTING MOVIES
stop every movie
close every movie saving no
try
-- OPEN THE ITEM
open source_file
set the target_path to ((results_folder as string) & new_name) as string
tell movie 1
-- IF THE MOVIE IS NOT EDITABLE, POST AN ALERT
if saveable is false then
error "This movie has previously been set so that it cannot be copied, edited, or saved."
end if
-- MOVIE PROCESSING STATEMENTS GO HERE
end tell
-- SAVE AND CLOSE THE MOVIE
export movie 1 to file target_path as MPEG4 using most recent settings
close movie 1
-- RESET THE APPLICATION SUPPRESS PROPERTY
my toggle_suppress(false)
on error error_msg number error_num
if the error_num is -128 then
my toggle_suppress(false)
error number -128
else
try
beep
display dialog error_msg buttons {"Cancel", "Continue"} default button 2 with icon 1
on error
my toggle_suppress(false)
error number -128
end try
end if
end try
my toggle_suppress(false)
end tell
end timeout
on error error_message
tell application "Finder"
activate
display dialog error_message buttons {"Cancel"} default button 1 giving up after 120
end tell
end try
end process_item

on toggle_suppress(status_flag)
tell application "QuickTime Player"
set ignore auto play to the status_flag
set ignore auto present to the status_flag
end tell
end toggle_suppress

on gestaltVersion_info(gestalt_code, string_length)
try
tell application "Finder" to ¬
copy my NumToHex((system attribute gestalt_code), ¬
string_length) to {a, b, c, d}
set the numeric_version to {a, b, c, d} as string
if a is "0" then set a to ""
set the version_string to (a & b & "." & c & "." & d) as string
return {numeric_version, version_string}
on error
return {"", "unknown"}
end try
end gestaltVersion_info

on NumToHex(hexData, stringLength)
set hexString to {}
repeat with i from stringLength to 1 by -1
set hexString to ((hexData mod 16) as string) & hexString
set hexData to hexData div 16
end repeat
return (hexString as string)
end NumToHex

sn(t)iff

Hier gibt's noch einen simplen QT export AppleScript
und einen Automator workflow für mehrere Dateien

macosxhints http://www.macosxhints.com/article.php?story=2005102017101662#comments