global these_items, parent_dir

on run
    tell application "Finder" to ¬
        set these_items to choose file multiple selections allowed yes
    do_with(these_items)
end run

on open these_items
    do_with(these_items)
end open

on do_with(these_items)
    get_parent_dir(((item 1 of these_items) as text))
    tell application "QuickTime Player 7"
        close every document saving no
        repeat with i from 1 to the count of these_items
            set this_item to (item i of these_items)
            if i is equal to 1 then
                make new document
                tell application "System Events" to ¬
                    set movie_name to name of this_item
            end if
            open this_item
            delay 2
            tell document 1
                rewind
                select all
                copy
                select none
            end tell
            close document 1 saving no
            tell document 1
                paste
            end tell
        end repeat
        save document 1 in ¬
            (parent_dir & movie_name & "_CONTIGOUS")
        close document 1
    end tell
end do_with

on get_parent_dir(the_item)
    set ASTID to AppleScript's text item delimiters
    set text item delimiters to ":"
    set dir_paths to text items 1 thru -2 of the_item
    set text item delimiters to ASTID
    set parent_dir to ""
    repeat with i in dir_paths
        set parent_dir to parent_dir & (i & ":")
    end repeat
end get_parent_dir