set Today to current date
set StartDate to date (text returned of (display dialog "Period Starts?" default answer date string of (Today - 7 * days)))
set EndDate to date (text returned of (display dialog "Period Ends?" default answer date string of (StartDate + 7 * days)))
set CName to date string of StartDate
set CName to words of CName
set CName to ((path to desktop) as string) & item 1 of CName & space & item 2 of CName & space & item 3 of CName & ".txt"
set CSVFile to open for access CName with write permission
set CSVLine to "Date" & tab & tab & tab & "Start Time" & tab & "End Time" & tab & "Description" & tab & "Client" & tab & tab & "Activity" & return
write CSVLine to CSVFile
try
    tell application "iCal"
        set EveryCal to name of every calendar
        set TheCal to item 1 of (choose from list EveryCal with prompt "Which Calendar" default items {item 1 of EveryCal} without multiple selections allowed)
        set TimeRecords to events of calendar TheCal where (start date of it > StartDate) and (end date of it < (EndDate + 1 * days))
        set TimeRecords to my sortEvents(TimeRecords)
        set RecList to {}
        repeat with ATimeRec in TimeRecords
            set CSVLine to {start date of ATimeRec, end date of ATimeRec, summary of ATimeRec, location of ATimeRec, description of ATimeRec}
            set RecList to RecList & {CSVLine}
        end repeat
    end tell
    repeat with Details in RecList
        set x1 to date string of item 1 of Details
        set off to offset of "," in x1
        set x1 to characters (off + 2) thru (length of x1) of x1 as string
        set CSVLine to x1 & tab & tab
        set CSVLine to CSVLine & (time string of item 1 of Details) & tab
        set CSVLine to CSVLine & (time string of item 2 of Details) & tab
        set CSVLine to CSVLine & (item 3 of Details) & tab
        set CSVLine to CSVLine & (item 4 of Details) & tab
        set CSVLine to CSVLine & (item 5 of Details) & return
        write CSVLine to CSVFile
    end repeat
on error
    close access CSVFile
end try
close access CSVFile
on sortEvents(theList)
    -- if there's only one event then it is, by definition, sorted
    if (count theList) = 1 then return theList
    -- if there are only two events then a simple check suffices
    if (count theList) = 2 then
        tell application "iCal"
            if start date of item 1 of theList < start date of item 2 of theList then
                return theList
            else
                return {item 2 of theList, item 1 of theList}
            end if
        end tell
    end if
    -- if we get here we have more than 2 items, so iterate through them
    set sorted to false -- assume they're out of order
    repeat until sorted = true
        set sorted to true
        repeat with i from 1 to (count theList) - 1
            tell application "iCal"
                -- check two items
                if start date of item i of theList > start date of item (i + 1) of theList then
                    -- they're out of order, so set the flag
                    set sorted to false
                    -- swap the items (via a temp object
                    copy item (i + 1) of theList to tmpEvent
                    set item (i + 1) of theList to item i of theList
                    set item i of theList to tmpEvent
                end if
            end tell
        end repeat
    end repeat
    -- and return the sorted list
    return theList
end sortEvents