Hallo liebes Forum,

In den Regeln von Apple Mail gibts die Möglichkeit, ein Script bei Erhalt einer Nachricht laufen zu lassen. Wäre es möglich in einer Autonachricht den Namen zu erwähnen, der das Mail geschickt hat?

Vielen Dank schon mal...

Was für eine Autonachricht?
Eine Email an eine andere Adresse oder ein Popup bei einem bestimmten Absender?

Gruß,
Schmiddl

Hallo, auch ich weiss zwar nicht genau, was Du suchst..

aber ich verwende dies:

Schau Dir das doch einfach mal an.... läuft bei mir prima....

Ich meine es so:

Wenn jemand eine Mail auf einen speziellen Mailaccount schickt, soll diese automatisch beantwortet werden und der Name des Absenders soll in dieser Automail erwähnt sein.

rene204

Habs installiert, verstehe das App aber nicht, was kann man damit?

*gg* Mail.App bietet dir eine Vorschau bei reinkommenden Mails und gibt dir dann verschiedene Möglichkeiten. Sehr nett (hab ich auch, Dank Tipp eines Gewissen Thomas R. damals ), aber es ist nicht, was du suchst.

Du kannst ja in den Regeln von Mal.app eine Auto-Antwort generieren, aber wie man das dann auch personalisiert, weiß ich leider nicht, sorry. Da müsste ggf. jemand mit Skript-Kenntnissen (Header-Abfrage) was zu sagen.

Diesen Jemand suche ich noch

Bin doch schon dabei und gleich fertig

CU
Schmiddl

Voila:
In den Scripteditor einfügen, sichern unter /Library/Scripts/Mail Scripts/Rule Actions/ als z.B. personalizedAnswer.scpt und in Mail bei Erfüllen einer bestimmten Bedingung ausführen lassen

on run
-- Nur zum Testen, wenn aus Scripteditor aufgerufen
tell application "Mail"
set theSelection to selection
if (count of theSelection) > 0 then
my answerPersonalized(theSelection)
end if
end tell
end run

on perform_mail_action(info)
tell application "Mail"
set selectedMessages to |SelectedMessages| of info
my answerPersonalized(selectedMessages)
end tell
end perform_mail_action

on answerPersonalized(emailList)
tell application "Mail"
repeat with thisMessage in emailList
set theSender to extract name from sender of thisMessage
set theSendersEmail to extract address from sender of thisMessage

-- mailContent bzw. mailSubject kannst du hier selber anpassen
set mailContent to "Hallo, " & theSender & ", danke für Ihre Nachfrage... Blabla" & return & return & "Mit freundlichen Grüßen," & return & "ICH"
set mailSubject to "Danke für Ihre Post!"


set thisAccount to (account of mailbox of thisMessage)
set theSender to extract name from sender of thisMessage
set theSendersEmail to extract address from sender of thisMessage
set newMessage to make new outgoing message with properties {subject:mailSubject, content:mailContent, account:thisAccount}
tell newMessage
set visible to false
make new to recipient at end of to recipients with properties {name:theSender, address:theSendersEmail}
send
end tell
end repeat
end tell
end answerPersonalized

Hoffe, dass alles klappt wg. der Zeilenumbrüche, aber bei mir funzt es so.

Viel Spaß,
Schmiddl

Uuuups,
die Zeilensind doppelt
Das zweite Mal können sie gelöscht werden

Trotzdem viel Spaß,
Schmiddl

Wow, werde es gleich probieren...

... set theSender to extract name from sender of thisMessage
set theSendersEmail to extract address from sender of thisMessage

sehe da nichts, das doppelt ist, beim einen mal ist es name und beim andern adress...

on run
-- Nur zum Testen, wenn aus Scripteditor aufgerufen
tell application "Mail"
set theSelection to selection
if (count of theSelection) > 0 then
my answerPersonalized(theSelection)
end if
end tell
end run

on perform_mail_action(info)
tell application "Mail"
set selectedMessages to |SelectedMessages| of info
my answerPersonalized(selectedMessages)
end tell
end perform_mail_action

on answerPersonalized(emailList)
tell application "Mail"
repeat with thisMessage in emailList
set theSender to extract name from sender of thisMessage
set theSendersEmail to extract address from sender of thisMessage

-- mailContent bzw. mailSubject kannst du hier selber anpassen
set mailContent to "Hallo, " & theSender & ", danke für Ihre Nachfrage... Blabla" & return & return & "Mit freundlichen Grüßen," & return & "ICH"
set mailSubject to "Danke für Ihre Post!"


set thisAccount to (account of mailbox of thisMessage)
set newMessage to make new outgoing message with properties {subject:mailSubject, content:mailContent, account:thisAccount}
tell newMessage
set visible to false
make new to recipient at end of to recipients with properties {name:theSender, address:theSendersEmail}
send
end tell
end repeat
end tell
end answerPersonalized

ok, kann ich es so einfügen?

Ich hab gar keinen Scripteditor übrigens.... :-|:-y




Gibts den nicht mehr mit Tiger und Automator?

Jupp, sieht ganz gut aus.
Scripteditor: hier vielleicht?
/Applications/AppleScript/Script\ Editor.app/

CU
Schmiddl

Der Absender stimmte noch nicht. So klappt es bei mir (einfach den kompletten answerPersonalized-Handler tauschen):

on answerPersonalized(emailList)
tell application "Mail"
repeat with thisMessage in emailList
set theSender to extract name from sender of thisMessage
set theSendersEmail to extract address from sender of thisMessage

-- mailContent bzw. mailSubject kannst du hier selber anpassen
set mailContent to "Hallo, " & theSender & ", danke für Ihre Nachfrage... Blabla" & return & return & "Mit freundlichen Grüßen," & return & "ICH"
set mailSubject to "Danke für Ihre Post!"


set thisAccount to (account of mailbox of thisMessage)
set newMessage to make new outgoing message with properties {sender:item 1 of email addresses of thisAccount, subject:mailSubject, content:mailContent, account:thisAccount}
tell newMessage
set visible to false
make new to recipient at end of to recipients with properties {name:theSender, address:theSendersEmail}
send
end tell
end repeat
end tell
end answerPersonalized

Neu ist, dass der empfangende Account für die Antwort als Absender eingesetzt wird. Sollte vorher auch schon, funzte aber nicht

Viel Spaß,
Schmiddl

Gabbo biste sicher das du keinen Skripteditor hast?? Schreibe Skripteditor mal mit "k" in Spotlight rein!